Apex and SOQL basics

When to write code

Choose clicks before code: configuration and Flow are faster to build and easier to maintain. Use Apex when you need complex logic, large data volumes, integrations or behaviour that Flow cannot express.

Apex is Salesforce's programming language. It looks like Java, is strongly typed, and runs on Salesforce's servers inside your org.

SOQL: querying data

SOQL (Salesforce Object Query Language) reads records. It looks like SQL SELECT, but always queries one object (with related fields) and has no SELECT *.

List<Account> accounts = [
    SELECT Id, Name, Industry
    FROM Account
    WHERE Industry = 'Education'
    ORDER BY Name
    LIMIT 10
];

for (Account acc : accounts) {
    System.debug(acc.Name);
}

You can traverse relationships, for example SELECT Name, Account.Name FROM Contact, and run SOQL in the Developer Console query editor to try queries.

Your first trigger

A trigger runs Apex before or after records are inserted, updated or deleted. Triggers always receive records in batches of up to 200, available in Trigger.new.

trigger LeadTrigger on Lead (before insert) {
    for (Lead l : Trigger.new) {
        if (l.LeadSource == null) {
            l.LeadSource = 'Web';
        }
    }
}

Because this is a before trigger, changing fields on Trigger.new is enough; no DML statement is needed to save them.

Governor limits and bulkification

Because many customers share the same servers, Salesforce enforces governor limits on each transaction:

Code must therefore be bulkified: never run a query or DML statement inside a loop. Query once, collect the results in a Set or Map, and update all records in one statement.

// Bad: one query per contact, fails for 200 records
for (Contact c : Trigger.new) {
    Account a = [SELECT Name FROM Account WHERE Id = :c.AccountId];
}

// Good: one query for the whole batch
Set<Id> accountIds = new Set<Id>();
for (Contact c : Trigger.new) {
    accountIds.add(c.AccountId);
}
Map<Id, Account> accounts = new Map<Id, Account>(
    [SELECT Id, Name FROM Account WHERE Id IN :accountIds]
);

Tests are required

Apex is written in a sandbox or Developer Edition org, never directly in production. Before you can deploy it, at least 75% of your Apex code must be covered by tests, and every trigger needs some coverage. Tests create their own data and check results with assertions:

@isTest
private class LeadTriggerTest {
    @isTest
    static void setsDefaultLeadSource() {
        Lead l = new Lead(LastName = 'Menon', Company = 'DevCrest');
        insert l;

        Lead saved = [SELECT LeadSource FROM Lead WHERE Id = :l.Id];
        Assert.areEqual('Web', saved.LeadSource);
    }
}